Webmaster Forum / ASP / General ASP Topics / July 2008

30,000 seconds is a long script time out ;)

Change to False, you don't want to buffer anyway (yes I know you are
flushing but this is simpler).

This is not a valid content type if you don't know what the content type is
use the fallback type:  "application/octet-stream"

Don't add the Content-Length header its a duplication, ASP adds that for
you.

How come you know the character encoding but don't know the content type?
Consider deleting this line or setting the content-type to the correct text
type.

No need for a flush when buffering is off.

Again no need for a flush and .End is draconian, only use it if you know
something bad will happen if you don't.  Even then design out the something
bad rather than use .End.

The response timeout is a clientside thing however normally response
timeouts related to the time it takes to get the first chunk of data not the
overall send time.

Juan wrote  on Thu, 3 Jul 2008 06:00:01 -0700:

This looks odd - you're looping from 0 to the size of the stream, yet you're
pushing out 128000 bytes at a time. I think you should be using

For i = 0 To oStream.Size Step 128000

Also, in your loop what happens when you reach the end of the stream?

This is how I handle download from one of my applications

           Set oStream = Server.CreateObject("ADODB.Stream")
           Call oStream.Open()
           oStream.Type = 1
           call oStream.LoadFromFile(strFilename)

           iDownload = 1
           If lcase(right(strfilename,4)) = ".pdf" then
               Response.ContentType = "application/pdf"
           else
               Response.ContentType = "application/octet-stream"
           end if
           Response.AddHeader "Content-Disposition", "filename=" &
strfilename & ";"

           Response.Buffer = False

           'stream out the file in chunks
           Do While Not (oStream.EOS)
               Response.BinaryWrite oStream.Read(1024 * 256)
           Loop

           oStream.Close
           Set oStream = Nothing

this reads the file into the stream (just like you already have), sets an
appropriate ContentType (as Anthony points out the one you use is not a
recognised MIME type), turns off buffering, and then writes out the stream
in 256kB chunks until there is nothing left to write to out (using
oStream.EOS to determine if the stream is at the end).

You really do need buffering turned off - it's entirely possible that the
80MB file is going over the defined ASP buffer limit and so you're getting
an ASP error thrown into the data, and that causes what appears to be a
timeout but is actually due to ASP terminating the script because it has
errored. So far with the above code I've had no trouble with files larger
than the defined ASP buffer limit, but I haven't tried it with anything as
large as your file.

FYI this is the routine I use for sending a file to response.

Sub SendFileToResponse(FilePath, FileName)

Const clChunkSize = 1048576 ' 1MB

Dim oStream, i
Response.Buffer = False

Response.ContentType = "application/octet-stream"
Response.AddHeader "Content-Disposition", _
 "attachment; Filename=" & FileName

Set oStream = Server.CreateObject("ADODB.Stream")
oStream.Type = 1 ' Binary
oStream.Open
oStream.LoadFromFile FilePath

For i = 1 To oStream.Size \ clChunkSize
  Response.BinaryWrite oStream.Read(clChunkSize)
Next
If (oStream.Size Mod clChunkSize) <> 0 Then
  Response.BinaryWrite oStream.Read(oStream.Size Mod clChunkSize)
End If
oStream.Close

End Sub

1MB buffer is a bit on the big side though 128K is a good choice.

Mister, any solution about it ??

any sample code that works fine ?? please

thanks in advance...