Webmaster Forum / ASP / Database Access / June 2008

This is not what you want -- it doesn't use a database.

This simple page allows the entry (but not deletion) of 8 slots for each
weekday (Monday thru Friday) for any week.  The current week is
displayed and the user can go forward or backward one week at a time.
A name of up to 12 characters can be entered for any (time) slot.
The slot names can be changed to "times"; that is, "Slot 1" might be
changed to "8:00 - 8:15", etc.  The data is stored in a text file which
does not have to exist.  Watch for word-wrap -- there are 236 lines.
To test, save it as "slots.asp" on your Web server then visit its URL.

<%@ Language="VBScript" %>
<%  Option Explicit
'****
'*  Display and maintain a weekly matrix of reservation time slots.
'****
  '*
  '*  Declare Constants
  '*
   Const cASP = "slots.asp"
   Const cTXT = "slots.txt"
   Const cDAZ = "Sun,Mon,Tue,Wed,Thu,Fri,Sat"
   Const cCHR = "^"
   Const cMAX = 8
  '*
  '*  Declare Globals
  '*
   Dim i, j, k
   Dim iDAY
       iDAY = Weekday(Date)
   Dim sRQS
       sRQS = Request.QueryString()
   Dim aSTR()
 ReDim aSTR(100)
   Dim iSTR
       iSTR = 0
   Dim sSTR
  '*
  '*  Declare Variables
  '*
   Dim arrDAT(5)
       arrDAT(0) = Date
   If IsDate(sRQS) Then
       arrDAT(0) = sRQS
       iDAY = Weekday(sRQS)
   End If
   If iDAY > vbSunday Then
       arrDAT(0) = DateAdd("d",-iDAY+1,arrDAT(0))
   End If
   For i = 1 To UBound(arrDAT)
       arrDAT(i) = DateAdd("d",1,arrDAT(i-1))
   Next
   Dim arrDAZ
       arrDAZ = Split(cDAZ,",")
   Dim arrWHO()
 ReDim arrWHO(5,cMAX)
  '*
  '*  Declare Objects
  '*
   Dim objDIC
   Set objDIC = CreateObject("Scripting.Dictionary")
  '*
  '*  Processing
  '*
   If Request.Form("Put") = "True" Then
       Slots("Get")
       Slots("Put")
   End If
   objDIC.RemoveAll
   Slots("Get")
   Call Table()

Sub Append(sSTR)
'****
'*  Appends strings to array entries ReDim as needed; (see "Concat()").
'****
   sSTR = sSTR & ""
   If iSTR > UBound(aSTR) Then ReDim Preserve aSTR(UBound(aSTR) + 100)
   aSTR(iSTR) = sSTR & vbCrLf
   iSTR = iSTR + 1
End Sub

Function Concat()
'****
'*  Concatenates array entries into a single string; (see "Append()").
'****
   Redim Preserve aSTR(iSTR)
   Concat = Replace(Join(aSTR,""),"`",Chr(34))
   Erase aSTR
   ReDim aSTR(100)
   iSTR = 0
End Function

Sub Slots(Action)
'****
'*  Display and maintain reservation time slots.
'****
  '*
  '*  Declare Variables
  '*
   Dim arrDAY
   Dim strDIC
   Dim strDIK
   Dim arrOTF
   Dim strOTF
   Dim arrPUT
 ReDim arrPUT(8)
   Dim strPUT
  '*
  '*  Declare Objects
  '*
   Dim objFSO
   Set objFSO = CreateObject("Scripting.FileSystemObject")
   Dim objOTF
  '*
  '*  Action?
  '*
   If Action = "Get" Then
      '*
      '*  Read file
      '*
       If objFSO.FileExists(Server.MapPath(cTXT)) Then
           Set objOTF = objFSO.OpenTextFile(Server.MapPath(cTXT),1)
           If Not objOTF.AtEndOfStream Then
               strOTF = objOTF.ReadAll
           End If
           Set objOTF = Nothing
       End If
      '*
      '*  Build dictionary and array
      '*
           arrOTF = Split(strOTF,vbCrLf)
       For k = 0 To UBound(arrOTF)
           If arrOTF(k) = "" Then Exit For
           arrDAY = Split(arrOTF(k),cCHR)
           strDIC = "_" & CStr(arrDAY(0))
           objDIC.Add strDIC, arrOTF(k)
          '*
           For i = 1 To UBound(arrWHO,1)
               If CDate(arrDAY(0)) = CDate(arrDAT(i)) Then
                   For j = 1 To UBound(arrWHO,2)
                       arrWHO(i,j) = arrDAY(j)
                   Next
              End If
           Next
       Next
   ElseIf Action = "Put" Then
      '*
      '*  Build/update dictionary
      '*
       For i = 1 To UBound(arrWHO,1)
           arrPUT(0) = Request.Form("WHO_" & i)
           strDIC = "_" & CStr(arrPUT(0))
           For j = 1 To UBound(arrWHO,2)
               arrPUT(j) = Request.Form("WHO_" & i & "_" & j)
           Next
           strPUT = Join(arrPUT,cCHR)
           If Not objDIC.Exists(strDIC) Then
               objDIC.Add strDIC, strPUT
           Else
              objDIC.Item(strDIC) = strPUT
           End If
       Next
      '*
      '*  Write file from dictionary
      '*
       Set objOTF = objFSO.OpenTextFile(Server.MapPath(cTXT),2,True)
       For Each strDIC in objDIC
           strDIK = objDIC.Item(strDIC)
           If strDIK <> String(8,cCHR) Then
               objOTF.WriteLine(strDIK)
           End If
       Next
       Set objOTF = Nothing
   End If
  '*
  '*  Destroy Objects
  '*
   Set objFSO = Nothing
End Sub

Sub Table()
'****
'*  Generate HTML table.
'****
   Append "<table align=`center` border=`0` width=`95%` class=`bord`>"
   Append "<tr>"
   Append "  <th>"
   Append "    <a href=`" & cASP & "?" & DateAdd("d",-7,arrDAT(0)) & "`
title=`Last Week`><<</a>"
   Append "    &nbsp;"
   Append "    <a href=`" & cASP & "` title=`This Week`>Date</a>"
   Append "    &nbsp;"
   Append "    <a href=`" & cASP & "?" & DateAdd("d",+7,arrDAT(0)) & "`
title=`Next Week`>>></a>"
   Append "    <hr>"
   Append "  </th>"
   For i = 1 To cMAX
       Append "  <th>Slot " & i & "<hr></th>"
   Next
   Append "</tr>"
   For i = 1 To 5
       Append "<tr height=`30`>"
       Append "  <th>"
       Append "    " & arrDAZ(i) & " -- " & arrDAT(i)
       Append "    <input type=`hidden` name=`WHO_" & i & "` value=`" &
arrDAT(i) & "`>"
       Append "  </th>"
       For j = 1 To cMAX
           Append "  <td>"
           If arrWHO(i,j) = "" Then
               Append "    <input type=`text` name=`WHO_" & i & "_" & j &
"` size=`12` maxlength=`12` class=`line`>"
           Else
               Append "    <input type=`hidden` name=`WHO_" & i & "_" & j &
"` value=`" & arrWHO(i,j) & "`>"
               Append "    &nbsp;<b>" & arrWHO(i,j) & "</b>"
           End If
           Append "  </td>"
       Next
       Append "</tr>"
   Next
   Append "</table>"
End Sub
%>
<html>
<head>
<title>rooms.htm</title>
<style type="text/css">
a { color:blue; text-decoration:none }
body,td, th { font-family:Arial; font-size:9pt }
.bord { border:solid 1px black }
.butt { background:white; width:100px }
.line { border:solid 1px white; border-bottom:solid 1px black }
</style>
</head>
<body>
<form action="<%=cASP%>" method="post">
<input type="hidden" name="Put" value="True">
<%=Concat()%>
<br>
&nbsp; &nbsp; &nbsp;
<input type="submit" class="butt" value="Save">
<input type="button" class="butt" value="Reload"
onclick="location.href='<%=cASP%>';">
&nbsp; &nbsp; &nbsp;
^{"Save" changes before changing weeks via the <a>blue</a> controls. &nbsp;
This facility does not yet support the removal of a slot's entry.}
</form>
</body>
</html>